- -

Creating a FlappyBird clone in Godot 3.5 devlog 1

- -

I just have a bit of experience with Godot and with gamedev in general, so I started with this game as it is pretty straight forward. On a high level the main characteristics of the game are:

Literally just one sprite going up and down.
Constant horizontal move of the world/player.
If you go through the gap in the pipes you score a point.
If you touch the pipes, the ground or go past the “ceiling” you lose.

The game was originally developed with Godot 4.0 alpha 8, but it didn’t support HTML5 (webassembly) export… so I backported to Godot 3.5 rc1.

Note: I’ve updated the game to Godot 4 and documented it on my FlappyBird devlog 2 entry.

Not going to specify all the details, only the needed parts and what could be confusing, as the source code is available and can be inspected; also this assumes minimal knowledge of Godot in general. Usually when I mention that a set/change of something it usually it’s a property and it can be found under the Inspector on the relevant node, unless stated otherwise; also, all scripts attached have the same name as the scenes, but in snake_case (scenes/nodes in PascalCase).

One thing to note, is that I started writing this when I finished the game, so it’s hard to go part by part, and it will be hard to test individual parts when going through this as everything is depending on each other. For the next devlog, I’ll do it as I go and it will include all the changes to the nodes/scripts as I was finding them, probably better idea and easier to follow.

The source code can be found at luevano/flappybirdgodot#godot-3.5 (godot-3.5 branch), it also contains the exported versions for HTML5, Windows and Linux (~~be aware that the sound might be too high and I’m too lazy to make it configurable, it was the last thing I added~~ on the latest version this is fixed and audio level is configurable now). Playable on itch.io (Godot 4 version):

<a href="https://lorentzeus.itch.io/flappybirdgodot">FlappyBirdGodot by Lorentzeus</a>

- -

Table of contents¶

Table of contents
Initial setup
- Directory structure
- Config
  - Default import settings
  - General settings
  - Keybindings
  - Layers
  -
-
Assets
- Importing
-
Scenes
- TileMaps
  - Default ground tiles
  -
- Player
- Other
- Game
- UI
  - Fonts
  - Scene setup
  -
- Main
-
Scripting
- Player
- WorldDetector
- WorldTiles
  - GroundTileMap
  - PipeTileMap
  -
- Saved data
- Game
- UI
- Main
-
Final notes and exporting
- Preparing the files
- Exporting
-

Initial setup¶

Directory structure¶

I’m basically going with what I wrote on Godot project structure recently, and probably with minor changes depending on the situation.

Config¶

Default import settings¶

Since this is just pixel art, the importing settings for textures needs to be adjusted so the sprites don’t look blurry. Go to Project -> Project settings… -> Import defaults and on the drop down select Texture, untick everything and make sure Compress/Mode is set to Lossless.

Project settings - Import defaults - Texture settings

General settings¶

It’s also a good idea to setup some config variables project-wide. To do so, go to Project -> Project settings… -> General, select Application/config and add a new property (there is a text box at the top of the project settings window) for game scale: application/config/game_scale for the type use float and then click on add; configure the new property to 3.0; On the same window, also add application/config/version as a string, and make it 1.0.0 (or whatever number you want).

Project settings - General - Game scale and version properties

For my personal preferences, also disable some of the GDScript debug warnings that are annoying, this is done at Project -> Project settings… -> General, select Debug/GDScript and toggle off Unused arguments, Unused signal and Return value discarded, and any other that might come up too often and don’t want to see.

Project settings - General - GDScript debug warnings

Finally, set the initial window size in Project -> Project settings… -> General, select Display/Window and set Size/Width and Size/Height to 600 and 800, respectively. As well as the Stretch/Mode to viewport , and Stretch/Aspect to keep:

Project settings - General - Initial window size

Keybindings¶

I only used 3 actions (keybindings): jump, restart and toggle_debug (optional). To add custom keybindings (so that the Input.something() API can be used), go to Project -> Project settings… -> Input Map and on the text box write jump and click add, then it will be added to the list and it’s just a matter of clicking the + sign to add a Physical key, press any key you want to be used to jump and click ok. Do the same for the rest of the actions.

Layers¶

Finally, rename the physics layers so we don’t lose track of which layer is which. Go to Project -> Layer Names -> 2d Physics and change the first 5 layer names to (in order): player, ground, pipe, ceiling and score.

Project settings - Layer Names - 2D Physics

Assets¶

For the assets I found out about a pack that contains just what I need: flappy-bird-assets by MegaCrash; I just did some minor modifications on the naming of the files. For the font I used Silver, and for the sound the resources from FlappyBird-N64 (which seems to be taken from 101soundboards.com which the orignal copyright holder is .Gears anyways).

Importing¶

Create the necessary directories to hold the respective assets and it’s just a matter of dragging and dropping, I used directories: res://entities/actors/player/sprites/, res://fonts/, res://levels/world/background/sprites/, res://levels/world/ground/sprites/, res://levels/world/pipe/sprites/, res://sfx/. For the player sprites, the -FileSystem window looks like this (entities/actor directories are really not necessary):

It should look similar for other directories, except maybe for the file extensions. For example, for the sfx:

Scenes¶

Now it’s time to actually create the game, by creating the basic scenes that will make up the game. The hardest part and the most confusing is going to be the TileMaps, so that goes first.

TileMaps¶

I’m using a scene called WorldTiles with a Node2D node as root called the same. With 2 different TileMap nodes as children named GroundTileMap and PipeTileMap (these are their own scene); yes 2 different TileMaps because we need 2 different physics colliders (in Godot 4.0 you can have a single TileMap with different physics colliders in it). Each node has its own script. It should look something like this:

I used the following directory structure:

Scene - WorldTiles - Directory structure

To configure the GroundTileMap, select the node and click on (empty) on the TileMap/Tile set property and then click on New TileSet, then click where the (empty) used to be, a new window should open on the bottom:

Click on the plus on the bottom left and you can now select the specific tile set to use. Now click on the yellow + New Single Tile, activate the grid and select any of the tiles. Should look like this:

We need to do this because for some reason we can’t change the snap options before selecting a tile. After selecting a random tile, set up the Snap Options/Step (in the Inspector) and set it to 16x16 (or if using a different tile set, to it’s tile size):

Now you can select the actual single tile. Once selected click on Collision, use the rectangle tool and draw the rectangle corresponding to that tile’s collision:

TileSet - Tile - Selection and collision

Do the same for the other 3 tiles. If you select the TileMap itself again, it should look like this on the right (on default layout it’s on the left of the Inspector):

The ordering is important only for the “underground tile”, which is the filler ground, it should be at the end (index 3); if this is not the case, repeat the process (it’s possible to rearrange them but it’s hard to explain as it’s pretty weird).

At this point the tilemap doesn’t have any physics and the cell size is wrong. Select the GroundTileMap, set the TileMap/Cell/Size to 16x16, the TileMap/Collision/Layer set to bit 2 only (ground layer) and disable any TileMap/Collision/Mask bits. Should look something like this:

TileMap - Cell size and collision configuration

Now it’s just a matter of repeating the same for the pipes (PipeTileMap), only difference is that when selecting the tiles you need to select 2 tiles, as the pipe is 2 tiles wide, or just set the Snap Options/Step to 32x16, for example, just keep the cell size to 16x16.

Default ground tiles¶

I added few default ground tiles to the scene, just for testing purposes but I left them there. These could be place programatically, but I was too lazy to change things. On the WorldTiles scene, while selecting the GroundTileMap, you can select the tiles you want to paint with, and left click in the grid to paint with the selected tile. Need to place tiles from (-8, 7) to (10, 7) as well as the tile below with the filler ground (the tile position/coordinates show at the bottom left, refer to the image below):

Player¶

On a new scene called Player with a KinematicBody2D node named Player as the root of the scene, then for the children: AnimatedSprite as Sprite, CollisionShape2D as Collision (with a circle shape) and 3 AudioStreamPlayers for JumpSound, DeadSound and HitSound. Not sure if it’s a good practice to have the audio here, since I did that at the end, pretty lazy. Then, attach a script to the Player node and then it should look like this:

Select the Player node and set the CollisionShape2D/Collision/Layer to 1 and the CollisionObject2D/Collision/Mask to 2 and 3 (ground and pipe).

For the Sprite node, when selecting it click on the (empty) for the AnimatedSprite/Frames property and click New SpriteFrames, click again where the (empty) used to be and ane window should open on the bottom:

Right off the bat, set the Speed to 10 FPS (bottom left) and rename default to bird_1. With the bird_1 selected, click on the Add frames from a Sprite Sheet, which is the second button under Animation Frames: which looks has an icon of a small grid (next to the folder icon), a new window will popup where you need to select the respective sprite sheet to use and configure it for importing. On the Select Frames window, change the Vertical to 1, and then select all 4 frames (Ctrl + Scroll wheel to zoom in):

After that, the SpriteFrames window should look like this:

Finally, make sure the Sprite node has the AnimatedSprite/Animation is set to bird_1 and that the Collision node is configured correctly for its size and position (I just have it as a radius of 7). As well as dropping the SFX files into the corresponding AudioStreamPlayer (into the AudioStreamPlayer/Stream property).

Other¶

These are really simple scenes that don’t require much setup:

CeilingDetector: just an Area2D node with a CollisionShape2D in the form of a rectangle (CollisionShape2D/Shape/extents to (120, 10)), stretched horizontally so it fits the whole screen. CollisionObject2D/Collision/Layer set to bit 4 (ceiling) and CollisionObject2D/Collision/Mask set to bit 1 (player).
ScoreDetector: similar to the CeilingDetector, but vertical (CollisionShape2D/Shape/extents to (2.5, 128)) and CollisionObject2D/Collision/Layer set to bit 1 (player).
WorldDetector: Node2D with a script attached, and 3 RayCast2D as children:
- NewTile: Raycast2D/Enabled to true (checked), Raycast2D/Cast To (0, 400), Raycast2D/Collision Mask to bit 2 (ground) and Node2D/Transform/Position to (152, -200)
- OldTile: same as “NewTile”, except for the Node2D/Transform/Position, set it to (-152, -200).
- OldPipe: same as “OldTile”, except for the Raycast2D/Collision Mask, set it to bit 3 (pipe).
-

Game¶

This is the actual Game scene that holds all the playable stuff, here we will drop in all the previous scenes; the root node is a Node2D and also has an attached script. Also need to add 2 additional AudioStreamPlayers for the “start” and “score” sounds, as well as a Sprite for the background (Sprite/Offset/Offset set to (0, 10)) and a Camera2D (Camera2D/Current set to true (checked)). It should look something like this:

The scene viewport should look something like the following:

UI¶

Fonts¶

We need some font Resources to style the Label fonts. Under the FileSystem window, right click on the fonts directory (create one if needed) and click on New Resource... and select DynamicFontData, save it in the “fonts” directory as SilverDynamicFontData.tres (Silver as it is the font I’m using) then double click the just created resource and set the DynamicFontData/Font Path to the actual Silver.ttf font (or whatever you want).

Then create a new resource and this time select DynamicFont, name it SilverDynamicFont.tres, then double click to edit and add the SilverDynamicFontData.tres to the DynamicFont/Font/Font Data property (and I personally toggled off the DynamicFont/Font/Antialiased property), now just set the DynamicFont/Settings/(Size, Outline Size, Outline Color) to 32, 1 and black, respectively (or any other values you want). It should look something like this:

Do the same for another DynamicFont which will be used for the score label, named SilverScoreDynamicFont.tres. Only changes are Dynamic/Settings/(Size, Outline Size) which are set to 128 and 2, respectively. The final files for the fonts should look something like this:

Resource - Dynamicfont - Directory structure

Scene setup¶

This has a bunch of nested nodes, so I’ll try to be concise here. The root node is a CanvasLayer named UI with its own script attached, and for the children:

MarginContainer: MarginContainer with Control/Margin/(Left, Top) set to 10 and Control/Margin/(Right, Bottom) set to -10.
- InfoContainer: VBoxContainer with Control/Theme Overrides/Constants/Separation set to 250.
  - ScoreContainer: VBoxContainer.
    - Score: Label with Label/Align set to Center, Control/Theme Overrides/Fonts/Font to the SilverScoreDynamicFont.tres, if needed adjust the DynamicFont settings.
    - HighScore: same as Score, escept for the Control/Theme Overrides/Fonts/Font which is set to SilverDynamicFont.tres.
    -
  - StartGame: Same as HighScore.
  -
- DebugContainer: VBoxContainer.
  - FPS: Label.
  -
- VersionContainer: VBoxContainer with BoxContainer/Alignment set to Begin.
  - Version: Label with Label/Align set to Right.
  -
-

The scene ends up looking like this:

Main¶

This is the final scene where we connect the Game and the UI. It’s made of a Node2D with it’s own script attached and an instance of Game and UI as it’s children.

This is a good time to set the default scene when we run the game by going to Project -> Project settings… -> General and in Application/Run set the Main Scene to the Main.tscn scene.

Scripting¶

I’m going to keep this scripting part to the most basic code blocks, as it’s too much code, for a complete view you can head to the source code.

As of now, the game itself doesn’t do anything if we hit play. The first thing to do so we have something going on is to do the minimal player scripting.

Player¶

The most basic code needed so the bird goes up and down is to just detect jump key presses and add a negative jump velocity so it goes up (y coordinate is reversed in godot…), we also check the velocity sign of the y coordinate to decide if the animation is playing or not.

class_name Player
-extends KinematicBody2D
-
-export(float, 1.0, 1000.0, 1.0) var JUMP_VELOCITY: float = 380.0
-
-onready var sprite: AnimatedSprite = $Sprite
-
-var gravity: float = 10 * ProjectSettings.get_setting("physics/2d/default_gravity")
-var velocity: Vector2 = Vector2.ZERO
-
-
-func _physics_process(delta: float) -> void:
-    velocity.y += gravity * delta
-
-    if Input.is_action_just_pressed("jump"):
-        velocity.y = -JUMP_VELOCITY
-
-    if velocity.y < 0.0:
-        sprite.play()
-    else:
-        sprite.stop()
-
-    velocity = move_and_slide(velocity)
-

You can play it now and you should be able to jump up and down, and the bird should stop on the ground (although you can keep jumping). One thing to notice is that when doing sprite.stop() it stays on the last frame, we can fix that using the code below (and then change sprite.stop() for _stop_sprite()):

func _stop_sprite() -> void:
-    if sprite.playing:
-        sprite.stop()
-    if sprite.frame != 0:
-        sprite.frame = 0
-

Where we just check that the last frame has to be the frame 0.

Now just a matter of adding other needed code for moving horizontally, add sound by getting a reference to the AudioStreamPlayers and doing sound.play() when needed, as well as handling death scenarios by adding a signal died at the beginning of the script and handle any type of death scenario using the below function:

func _emit_player_died() -> void:
-    # bit 2 corresponds to pipe (starts from 0)
-    set_collision_mask_bit(2, false)
-    dead = true
-    SPEED = 0.0
-    emit_signal("died")
-    # play the sounds after, because yield will take a bit of time,
-    # this way the camera stops when the player "dies"
-    velocity.y = -DEATH_JUMP_VELOCITY
-    velocity = move_and_slide(velocity)
-    hit_sound.play()
-    yield(hit_sound, "finished")
-    dead_sound.play()
-

Finally need to add the actual checks for when the player dies (like collision with ground or pipe) as well as a function that listens to a signal for when the player goes to the ceiling.

WorldDetector¶

The code is pretty simple, we just need a way of detecting if we ran out of ground and send a signal, as well as sending as signal when we start detecting ground/pipes behind us (to remove it) because the world is being generated as we move. The most basic functions needed are:

func _was_colliding(detector: RayCast2D, flag: bool, signal_name: String) -> bool:
-    if detector.is_colliding():
-        return true
-    if flag:
-        emit_signal(signal_name)
-        return false
-    return true
-
-
-func _now_colliding(detector: RayCast2D, flag: bool, signal_name: String) -> bool:
-    if detector.is_colliding():
-        if not flag:
-            emit_signal(signal_name)
-            return true
-    return false
-

We need to keep track of 3 “flags”: ground_was_colliding, ground_now_colliding and pipe_now_colliding (and their respective signals), which are going to be used to do the checks inside _physics_process. For example for checking for new ground: ground_now_colliding = _now_colliding(old_ground, ground_now_colliding, "ground_started_colliding").

WorldTiles¶

This script is what handles the GroundTileMap as well as the PipeTileMap and just basically functions as a “Signal bus” connecting a bunch of signals from the WorldDetector with the TileMaps and just tracking how many pipes have been placed:

export(int, 2, 20, 2) var PIPE_SEP: int = 6
-var tiles_since_last_pipe: int = PIPE_SEP - 1
-
-
-func _on_WorldDetector_ground_stopped_colliding() -> void:
-    emit_signal("place_ground")
-
-    tiles_since_last_pipe += 1
-    if tiles_since_last_pipe == PIPE_SEP:
-        emit_signal("place_pipe")
-        tiles_since_last_pipe = 0
-
-
-func _on_WorldDetector_ground_started_colliding() -> void:
-    emit_signal("remove_ground")
-
-
-func _on_WorldDetector_pipe_started_colliding() -> void:
-    emit_signal("remove_pipe")
-

GroundTileMap¶

This is the node that actually places the ground tiles upong receiving a signal. In general, what you want is to keep track of the newest tile that you need to place (empty spot) as well as the last tile that is in the tilemap (technically the first one if you count from left to right). I was experimenting with enums so I used them to define the possible Ground tiles:

enum Ground {
-    TILE_1,
-    TILE_2,
-    TILE_3,
-    TILE_DOWN_1,
-}
-

This way you can just select the tile by doing Ground.TILE_1, which will correspond to the int value of 0. So most of the code is just:

# old_tile is the actual first tile, whereas the new_tile_position
-#   is the the next empty tile; these also correspond to the top tile
-const _ground_level: int = 7
-const _initial_old_tile_x: int = -8
-const _initial_new_tile_x: int = 11
-var old_tile_position: Vector2 = Vector2(_initial_old_tile_x, _ground_level)
-var new_tile_position: Vector2 = Vector2(_initial_new_tile_x, _ground_level)
-
-
-func _place_new_ground() -> void:
-    set_cellv(new_tile_position, _get_random_ground())
-    set_cellv(new_tile_position + Vector2.DOWN, Ground.TILE_DOWN_1)
-    new_tile_position += Vector2.RIGHT
-
-
-func _remove_first_ground() -> void:
-    set_cellv(old_tile_position, -1)
-    set_cellv(old_tile_position + Vector2.DOWN, -1)
-    old_tile_position += Vector2.RIGHT
-

Where you might notice that the _initial_new_tile_x is 11, instead of 10, refer to Default ground tiles where we placed tiles from -8 to 10, so the next empty one is 11. These _place_new_ground and _remove_first_ground functions are called upon receiving the signal.

PipeTileMap¶

This is really similar to the GroundTileMap code, instead of defining an enum for the ground tiles, we define it for the pipe patterns (because each pipe is composed of multiple pipe tiles). If your pipe tile set looks like this (notice the index):

Then you can use the following “pipe patterns”:

var pipe: Dictionary = {
-    PipePattern.PIPE_1: [0, 1, 2, 2, 2, 2, 2, 2, 3, 4, -1, -1, -1, 0, 1, 2],
-    PipePattern.PIPE_2: [0, 1, 2, 2, 2, 2, 2, 3, 4, -1, -1, -1, 0, 1, 2, 2],
-    PipePattern.PIPE_3: [0, 1, 2, 2, 2, 2, 3, 4, -1, -1, -1, 0, 1, 2, 2, 2],
-    PipePattern.PIPE_4: [0, 1, 2, 2, 2, 3, 4, -1, -1, -1, 0, 1, 2, 2, 2, 2],
-    PipePattern.PIPE_5: [0, 1, 2, 2, 3, 4, -1, -1, -1, 0, 1, 2, 2, 2, 2, 2],
-    PipePattern.PIPE_6: [0, 1, 2, 3, 4, -1, -1, -1, 0, 1, 2, 2, 2, 2, 2, 2]
-}
-

Now, the pipe system requires a bit more of tracking as we need to instantiate a ScoreDetector here, too. I ended up keeping track of the placed pipes/detectors by using a “pipe stack” (and “detector stack”) which is just an array of placed objects from which I pop the first when deleting them:

onready var _pipe_sep: int = get_parent().PIPE_SEP
-const _pipe_size: int = 16
-const _ground_level: int = 7
-const _pipe_level_y: int = _ground_level - 1
-const _initial_new_pipe_x: int = 11
-var new_pipe_starting_position: Vector2 = Vector2(_initial_new_pipe_x, _pipe_level_y)
-var pipe_stack: Array
-
-# don't specify type for game, as it results in cyclic dependency,
-# as stated here: https://godotengine.org/qa/39973/cyclic-dependency-error-between-actor-and-actor-controller
-onready var game = get_parent().get_parent()
-var detector_scene: PackedScene = preload("res://levels/detectors/score_detector/ScoreDetector.tscn")
-var detector_offset: Vector2 = Vector2(16.0, -(_pipe_size / 2.0) * 16.0)
-var detector_stack: Array
-

The detector_offset is just me being picky. For placing a new pipe, we get the starting position (bottom pipe tile) and build upwards, then instantiate a new ScoreDetector (detector_scene) and set it’s position to the pipe starting position plus the offset, so it’s centered in the pipe, then just need to connect the body_entered signal from the detector with the game, so we keep track of the scoring. Finally just add the placed pipe and detector to their corresponding stacks:

func _place_new_pipe() -> void:
-    var current_pipe: Vector2 = new_pipe_starting_position
-    for tile in pipe[_get_random_pipe()]:
-        set_cellv(current_pipe, tile)
-        current_pipe += Vector2.UP
-
-    var detector: Area2D = detector_scene.instance()
-    detector.position = map_to_world(new_pipe_starting_position) + detector_offset
-    detector.connect("body_entered", game, "_on_ScoreDetector_body_entered")
-    detector_stack.append(detector)
-    add_child(detector)
-
-    pipe_stack.append(new_pipe_starting_position)
-    new_pipe_starting_position += _pipe_sep * Vector2.RIGHT
-

For removing pipes, it’s really similar but instead of getting the position from the next tile, we pop the first element from the (pipe/detector) stack and work with that. To remove the cells we just set the index to -1:

func _remove_old_pipe() -> void:
-    var current_pipe: Vector2 = pipe_stack.pop_front()
-    var c: int = 0
-    while c < _pipe_size:
-        set_cellv(current_pipe, -1)
-        current_pipe += Vector2.UP
-        c += 1
-
-    var detector: Area2D = detector_stack.pop_front()
-    remove_child(detector)
-    detector.queue_free()
-

These functions are called when receiving the signal to place/remove pipes.

Saved data¶

Before proceeding, we require a way to save/load data (for the high scores). We’re going to use the ConfigFile node that uses a custom version of the ini file format. Need to define where to save the data:

const DATA_PATH: String = "user://data.cfg"
-const SCORE_SECTION: String = "score"
-var _data: ConfigFile
-

Note that user:// is a OS specific path in which the data can be stored on a per user basis, for more: File paths. Then, a way to load the save file:

func _load_data() -> void:
-    # create an empty file if not present to avoid error while loading settings
-    var file: File = File.new()
-    if not file.file_exists(DATA_PATH):
-        file.open(DATA_PATH, file.WRITE)
-        file.close()
-
-    _data = ConfigFile.new()
-    var err: int = _data.load(DATA_PATH)
-    if err != OK:
-        print("[ERROR] Cannot load data.")
-

A way to save the data:

func save_data() -> void:
-    var err: int = _data.save(DATA_PATH)
-    if err != OK:
-        print("[ERROR] Cannot save data.")
-

And of course, a way to get and set the high score:

func set_new_high_score(high_score: int) -> void:
-    _data.set_value(SCORE_SECTION, "high_score", high_score)
-
-
-func get_high_score() -> int:
-    return _data.get_value(SCORE_SECTION, "high_score")
-

Then, whenever this script is loaded we load the data and if it’s a new file, then add the default high score of 0:

func _ready() -> void:
-    _load_data()
-
-    if not _data.has_section(SCORE_SECTION):
-        set_new_high_score(0)
-        save_data()
-

Now, this script in particular will need to be a Singleton (AutoLoad), which means that there will be only one instance and will be available across all scripts. To do so, go to Project -> Project settings… -> AutoLoad and select this script in the Path: and add a Node Name: (I used SavedData, if you use something else, be careful while following this devlog) which will be the name we’ll use to access the singleton. Toggle on Enable if needed, it should look like this:

Project settings - AutoLoad - SavedData singleton

Game¶

The game script it’s also like a “Signal bus” in the sense that it connects all its childs’ signals together, and also has the job of starting/stopping the _process and _physics_process methods from the childs as needed. First, we need to define the signals and and references to all child nodes:

signal game_started
-signal game_over
-signal new_score(score, high_score)
-
-onready var player: Player = $Player
-onready var background: Sprite= $Background
-onready var world_tiles: WorldTiles = $WorldTiles
-onready var ceiling_detector: Area2D = $CeilingDetector
-onready var world_detector: Node2D = $WorldDetector
-onready var camera: Camera2D = $Camera
-onready var start_sound: AudioStreamPlayer = $StartSound
-onready var score_sound: AudioStreamPlayer = $ScoreSound
-

It’s important to get the actual “player speed”, as we’re using a scale to make the game look bigger (remember, pixel art), to do so we need a reference to the game_scale we setup at the beginning and compute the player_speed:

var _game_scale: float = ProjectSettings.get_setting("application/config/game_scale")
-var player_speed: float
-
-
-func _ready() -> void:
-    scale = Vector2(_game_scale, _game_scale)
-    # so we move at the actual speed of the player
-    player_speed = player.SPEED / _game_scale
-

This player_speed will be needed as we need to move all the nodes (Background, Camera, etc.) in the x axis as the player is moving. This is done in the _physics_process:

func _physics_process(delta: float) -> void:
-    ceiling_detector.move_local_x(player_speed * delta)
-    world_detector.move_local_x(player_speed * delta)
-    background.move_local_x(player_speed * delta)
-    camera.move_local_x(player_speed * delta)
-

We also need a way to start and stop the processing of all the nodes:

func _set_processing_to(on_off: bool, include_player: bool = true) -> void:
-    set_process(on_off)
-    set_physics_process(on_off)
-    if include_player:
-        player.set_process(on_off)
-        player.set_physics_process(on_off)
-    world_tiles.set_process(on_off)
-    world_tiles.set_physics_process(on_off)
-    ceiling_detector.set_process(on_off)
-    ceiling_detector.set_physics_process(on_off)
-

Where the player is a special case, as when the player dies, it should still move (only down), else it would just freeze in place. In _ready we connect all the necessary signals as well as initially set the processing to false using the last function. To start/restart the game we need to keep a flag called is_game_running initially set to false and then handle the (re)startability in _input:

func _input(event: InputEvent) -> void:
-    if not is_game_running and event.is_action_pressed("jump"):
-        _set_processing_to(true)
-        is_game_running = true
-        emit_signal("game_started")
-        start_sound.play()
-
-    if event.is_action_pressed("restart"):
-        get_tree().reload_current_scene()
-

Then we handle two specific signals:

func _on_Player_died() -> void:
-    _set_processing_to(false, false)
-    emit_signal("game_over")
-
-
-func _on_ScoreDetector_body_entered(body: Node2D) -> void:
-    score += 1
-    if score > high_score:
-        high_score = score
-        SavedData.set_new_high_score(high_score)
-        SavedData.save_data()
-    emit_signal("new_score", score, high_score)
-    score_sound.play()
-

When the player dies, we set all processing to false, except for the player itself (so it can drop all the way to the ground). Also, when receiving a “scoring” signal, we manage the current score, as well as saving the new high score when applicable, note that we need to read the high_score at the beginning by calling SavedData.get_high_score(). This signal we emit will be received by the UI so it updates accordingly.

UI¶

First thing is to get a reference to all the child Labels, an initial reference to the high score as well as the version defined in the project settings:

onready var fps_label: Label = $MarginContainer/DebugContainer/FPS
-onready var version_label: Label = $MarginContainer/VersionContainer/Version
-onready var score_label: Label = $MarginContainer/InfoContainer/ScoreContainer/Score
-onready var high_score_label: Label = $MarginContainer/InfoContainer/ScoreContainer/HighScore
-onready var start_game_label: Label = $MarginContainer/InfoContainer/StartGame
-
-onready var _initial_high_score: int = SavedData.get_high_score()
-
-var _version: String = ProjectSettings.get_setting("application/config/version")
-

Then set the initial Label values as well as making the fps_label invisible:

func _ready() -> void:
-    fps_label.visible = false
-    version_label.set_text("v%s" % _version)
-    high_score_label.set_text("High score: %s" % _initial_high_score)
-

Now we need to handle the fps_label update and toggle:

func _input(event: InputEvent) -> void:
-    if event.is_action_pressed("toggle_debug"):
-        fps_label.visible = !fps_label.visible
-
-
-func _process(delta: float) -> void:
-    if fps_label.visible:
-        fps_label.set_text("FPS: %d" % Performance.get_monitor(Performance.TIME_FPS))
-

Finally the signal receiver handlers which are straight forward:

func _on_Game_game_started() -> void:
-    start_game_label.visible = false
-    high_score_label.visible = false
-
-
-func _on_Game_game_over() -> void:
-    start_game_label.set_text("Press R to restart")
-    start_game_label.visible = true
-    high_score_label.visible = true
-
-
-func _on_Game_new_score(score: int, high_score: int) -> void:
-    score_label.set_text(String(score))
-    high_score_label.set_text("High score: %s" % high_score)
-

Main¶

This is the shortest script, it just connects the signals between the Game and the UI:

onready var game: Game = $Game
-onready var ui: UI = $UI
-
-var _game_over: bool = false
-
-
-func _ready() -> void:
-    game.connect("game_started", ui, "_on_Game_game_started")
-    game.connect("game_over", ui, "_on_Game_game_over")
-    game.connect("new_score", ui, "_on_Game_new_score")
-

Final notes and exporting¶

At this point the game should be fully playable (if any detail missing feel free to look into the source code linked at the beginning). Only thing missing is an icon for the game; I did one pretty quicly with the assets I had.

Preparing the files¶

If you followed the directory structure I used, then only thing needed is to transform the icon to a native Windows ico format (if exporting to Windows, else ignore this part). For this you need ImageMagick or some other program that can transform png (or whatever file format you used for the icon) to ico. I used [Chocolatey][https://chocolatey.org/] to install imagemagick, then to convert the icon itself used: magick convert icon.png -define icon:auto-resize=256,128,64,48,32,16 icon.ico as detailed in Godot‘s Changing application icon for Windows.

Exporting¶

You need to download the templates for exporting as detailed in Godot‘s Exporting projects. Basically you go to Editor -> Manage Export Templates… and download the latest one specific to your Godot version by clicking on Download and Install.

If exporting for Windows then you also need to download rcedit from here. Just place it wherever you want (I put it next to the Godot executable).

Then go to Project -> Export… and the Window should be empty, add a new template by clicking on Add... at the top and then select the template you want. I used HTML5, Windows Desktop and Linux/X11. Really the only thing you need to set is the “Export Path” for each template, which is te location of where the executable will be written to, and in the case of the Windows Desktop template you could also setup stuff like Company Name, Product Name, File/Product Version, etc..

Once the templates are setup, select any and click on Export Project at the bottom, and make sure to untoggle Export With Debug in the window that pops up, this checkbox should be at the bottom of the new window.

- -

- - - - Next - - - - - - - Index - - - - - - - Previous - - -

- - -

By David Luévano

Created: Sun, May 29, 2022 @ 03:38 UTC

Modified: Sat, Aug 26, 2023 @ 04:45 UTC

Tags: -english, gamedev, gdscript, godot

- -

Porting the FlappyBird clone to Godot 4.1 devlog 2

- -

As stated in my FlappyBird devlog 1 entry I originally started the clone in Godot 4, then backported back to Godot 3 because of HTML5 support, and now I’m porting it back again to Godot 4 as there is support again and I want to start getting familiar with it for future projects.

The source code can be found at luevano/flappybirdgodot (main branch). Playable at itch.io:

<a href="https://lorentzeus.itch.io/flappybirdgodot">FlappyBirdGodot by Lorentzeus</a>

- -

Table of contents¶

Table of contents
Porting to Godot 4
- General changes
- Player
- World
  - Scene
  - Script
  -
-
Changes and improvements
- Audio
- Event bus
- UI
- Misc
-

Porting to Godot 4¶

Disclaimer: I started the port back in Godot 4.0 something and left the project for a while, then opened the project again in Godot 4.1, and it didn’t ask to convert anything so probably nowadays the conversion is better. Godot’s documentation is pretty useful, I looked at the GDScript reference and GDScript exports and that helped a lot.

General changes¶

These include the first changes for fixing some of the conflicting code to at least make it run (no gameplay) as well as project settings adjustments.

Changing the default import settings for pixel art no longer works (though it’s worth to double check as they changed from Texture to a Texture2D). The important parameter to change is the Filter for the textures.
- Change by going to the Project Settings at General -> Rendering -> Textures and set the Canvas Textures -> Default Texture Filter to “Nearest”.
-
Re-set the InputMap as the system probably changed from Godot 3 to Godot 4.
For SavedData singleton, change from File to ConfigFile and refactor. This is really not needed for making it run, but I changed this right away.
Remove velocity property of Player which is already included in CharacterBody2D.
Disable all TileMap related code as tile maps have changed drastically, they need more effort to covnert.
Change String(int) to str(int).

Player¶

Now that the game at least runs, next thing is to make it “playable”:

AnimatedSprite changed to AnimatedSprite2D (with the inclusion of AnimatedSprite3D). This node type changed with the automatic conversion.
- Instead of checking if an animation is playing with the the playing property, the method is_playing() needs to be used.
-
The default_gravity from the ProjectSettings no longer needs to be multiplied by 10 to have reasonable numbers. The default is now 980 instead of 98. I later changed this when refactoring the code and fine-tuning the feel of the movement.
The Collision mask can be changed programatically with the set_collision_mask_value (and similar with the layer). Before, the mask/layer was specified by the bit which started from 0, but now it is accessed by the layer_number which starts from 1.

World¶

This is the most challenging part as the TileMap system changed drastically, it is basically a from the ground up redesign, luckily the TileMaps I use are really simple. Since this is not intuitive from the get-go, I took some notes on the steps I took to set up the world TileMap.

Scene¶

Instead of using one scene per TileMap only one TileMap can be used with multiple Atlas in the TileSet. Multiple physics layers can now be used per TileSet so you can separate the physics collisions on a per Atlas or Tile basis. The inclusion of Tile patterns also helps when working with multiple Tiles for a single cell “placement”. How I did it:

Created one scene with one TileMap node, called WorldTileMap.tscn, with only one TileSet as multiple Atlas‘ can be used (this would be a single TileSet in Godot 3).
- To add a TileSet, select the WorldTileMap and go to Inspector -> TileMap -> TileSet then click on “” and then “New TileSet” button.
- To manipulate a TileSet, it needs to be selected, either by clicking in the Inspector section or on the bottom of the screen (by default) to the left of TileMap, as shown in the image below.
-

TileMap's TileSet selection highlighted in red, "Add" button in green.

Add two Atlas to the TileSet (one for the ground tiles and another for the pipes) by clicking on the “Add” button (as shown in the image above) and then on “Atlas”.
By selecting an atlas and having the “Setup” selected, change the Name to something recognizable like ground and add the texture atlas (the spritesheet) by dragging and dropping in the “” Texture field, as shown in the image below. Take a not of the ID, they start from 0 and increment for each atlas, but if they’re not 0 and 1 change them.

TileSet atlas setup selection highlighted in red, atlas name and id in green.

I also like to delete unnecessary tiles (for now) by selecting the atlas “Setup” and the “Eraser” tool, as shown in the image below. Then to erase tiles just select them and they’ll be highlighted in black, once deleted they will be grayed out. If you want to activate tiles again just deselect the “Eraser” tool and select wanted tiles.

Atlas setup erase tiles. "Setup" selection and "Eraser" tool highlighted in red and green, respectively. — Atlas setup erase tiles. “Setup” selection and “Eraser” tool highlighted in red and green, respectively.

For the pipes it is a good idea to modify the “tile width” for horizontal 1x2 tiles. This can be acomplished by removing all tiles except for one, then going to the “Select” section of the atlas, selecting a tile and extending it either graphically by using the yellow circles or by using the properties, as shown in the image below.

Atlas resize tile. "Select" selection and "Size in Atlas" highlighted in red and green, respectively. — Atlas resize tile. “Select” selection and “Size in Atlas” highlighted in red and green, respectively.

Add physics (collisions) by selecting the WorldTileMap‘s TileSet and clicking on “Add Element” at the TileMap -> TileSet -> Physics Layer twice, one physics layer per atlas. Then set the collision’s layers and masks accordingly (ground on layer 2, pipe on 3). In my case, based on my already set layers.
- This will enable physics properties on the tiles when selecting them (by selecting the atlas, being in the correct “Select” section and selecting a tile) and start drawing a polygon with the tools provided. This part is hard to explain in text, but below is an image of how it looks once the polygon is set.
-

Tile add physics polygon in Physics Layer 0. — Tile add physics polygon on physics layer 0.

- Notice that the polygon is drawn in *Physics Layer 0*. Using the grid option to either `1` or `2` is useful when drawing the polygon, make sure the polygon closes itself or it wont be drawn.
-

Create a tile pattern by drawing the tiles wanted in the editor and then going to the Patterns tab (to the right of Tiles) in the TileMap, selecting all tiles wanted in the pattern and dragging the tiles to the Patterns window. Added patterns will show in this window as shown in the image below, and assigned with IDs starting from 0.

Script¶

Basically merged all 3 scripts (ground_tile_map.gd, pipe_tile_map.gd and world_tiles.gd) into one (world_tile_map.gd) and immediatly was able to delete a lot of signal calls between those 3 scripts and redundant code.

The biggest change in the scripting side are the functions to place tiles. For Godot 3:

# place single tile in specific cell
-void set_cell(x: int, y: int, tile: int, flip_x: bool = false, flip_y: bool = false, transpose: bool = false, autotile_coord: Vector2 = Vector2( 0, 0 ))
-void set_cellv(position: Vector2, tile: int, flip_x: bool = false, flip_y: bool = false, transpose: bool = false, autotile_coord: Vector2 = Vector2( 0, 0 ))
-

Whereas in Godot 4:

# place single tile in specific cell
-void set_cell(layer: int, coords: Vector2i, source_id: int = -1, atlas_coords: Vector2i = Vector2i(-1, -1), alternative_tile: int = 0)
-# erase tile at specific cell
-void erase_cell(layer: int, coords: Vector2i)
-

How to use these functions in Godot 4 (new properties or differences/changes):

layer: for my case I only use 1 layer so it is always set to 0.
coords: would be the equivalent to position for set_cellv in Godot 3.
source_id: which atlas to use (ground: 0 or pipe 1).
atlas_coords: tile to use in the atlas. This would be the equivalent to tile in Godot 3.
alternative_tile: for tiles that have alternatives such as mirrored or rotated tiles, not required in my case.

Setting source_id=-1, atlas_coords=Vector21(-1,-1) or alternative_tile=-1 will delete the tile at coords, similar to just using erase_cell.

With the addition to Tile patterns (to place multiple tiles), there is a new function:

# place pattern
-void set_pattern(layer: int, position: Vector2i, pattern: TileMapPattern)
-

Where position has the same meaning as coords in set_cell/erase_cell, not sure why it has a different name. The pattern can be obtained by using get_pattern method on the tile_set property of the TileMap. Something like:

var pattern: TileMapPattern = tile_set.get_pattern(index)
-

Other than that, Vector2 needs to be changed to Vector2i.

Changes and improvements¶

General changes and additions that have nothing to do with porting to Godot 4, things I wanted to add regardless of the version.

Audio¶

The audio in the Godot 3 version was added in the last minute and it was blasting by default with no option to decrease the volume or mute it. To deal with this:

Refactored the code into a single scene/script to have better control.
Added a volume control slider by following this GDQuest guide.
Added a mute button, following the same principle as with the volume control.

The basic code required for these features is the following:

# get audio bus index
-var audio_bus_name: String = "Master"
-var _bus: int = AudioServer.get_bus_index(audio_bus_name)
-
-# change the volume
-var linear_volume: float = 0.5 # 50%, needs to be between 0.0 and 1.0
-var db_volume: float = linear_to_db(linear_volume)
-AudioServer.set_bus_volume_db(_bus, db_volume)
-
-# mute
-AudioServer.set_bus_mute(_bus, true) # false to unmute
-

Just be careful with how the linear_volume is set (from a button or slider) as it has to be between 0.0 and 1.0.

Event bus¶

Moved all the signal logic into an event bus to get rid of the coupling I had. This is accomplished by:

Creating a singleton (autoload) script which I called event.gd and can be accessed with Event.
All the signals are now defined in event.gd.
When a signal needs to be emited instead of emitting the signal from any particular script, emit it from the event bus with Event.<signal_name>.emit(<optional_args>).
When connecting to a signal instead of taking a reference to where the signal is defined, simply connect it with with Event.<signal_name>.connect(<callable>[.bind(<optional_args>)])
- For signals that already send arguments to the callable, they do not need to be specified in bind, only extras are needed here.
-

UI¶

Really the only UI I had before was for rendering fonts, and the way fonts work changed a bit. Before, 3 resources were needed as noted in my previous entry:

Font file itself (.ttf for example).
DynamicFontData: used to point to a font file (.ttf) and then used as base resource.
DynamicFont: usable in godot control nodes which holds the DynamicFontData and configuration such as size.

Now only 1 resource is needed: FontFile which is the .ttf file itself or a godot-created resource. There is also a FontVariation option, which takes a FontFile and looks like its used to create fallback options for fonts. The configuration (such as size) is no longer held in the font resource, but rather in the parent control node (like a Label). Double clicking on the .ttf file and disabling antialiasing and compression is something that might be needed. Optionally create a FontLabelSettings which will hold the .ttf file and used as base for Labels. Use “Make Unique” for different sizes. Another option is to use Themes and Variations.

I also created the respective volume button and slider UI for the added audio functionality as well as creating a base Label to avoid repeating configuration on each Label node.

Misc¶

Small changes that don’t affect much:

Updated @export to @export_range. The auto conversion didn’t use the correct annotation and instead used a comment.
Refactored the game_scale methodolgy as it was inconsistent. Now only one size is used as base and everything else is just scaled with the root Window.
Got rid of the FPS monitoring, was only using it for debugging purposes back then.

- -

- - - - Next - - - - - - - Index - - - - - - - Previous - - -

- - -

By David Luévano

Created: Sun, Aug 27, 2023 @ 23:28 UTC

Modified: Fri, Sep 01, 2023 @ 15:29 UTC

Tags: -english, gamedev, gdscript, godot

- -

Final improvements to the FlappyBird clone and Android support devlog 3

- -

Decided to conclude my FlappyBird journey with one last set of improvements, following up on devlogs 1 and 2. Focusing on refactoring, better UI, sprite selection and Android support.

I missed some features that I really wanted to get in but I’m already tired of working on this toy project and already eager to move to another one. Most of the features I wanted to add are just QoL UI enhancements and extra buttons basically.

The source code can be found at luevano/flappybirdgodot. Playable at itch.io:

<a href="https://lorentzeus.itch.io/flappybirdgodot">FlappyBirdGodot by Lorentzeus</a>

- -

Table of contents¶

Table of contents
Refactoring
Improvements
- Background parallax
- Sprite switcher
- Save data
-
Android
Misc

Refactoring¶

The first part for my refactor was to move everything out of the src/ directory into the root directory of the git repository, organizing it a tiny bit better, personal preference from what I’ve learned so far. I also decided to place all the raw aseprite assets next to the imported one, this way its easier to make modifications and then save directly in the same directory. Also, a list of other refactoring done:

The way I handled the gameplay means that I needed to make the camera, background and the (ceiling and tiles) “detectors” move along with the player, while restricting their movement in the x axis, really hacky. Instead, I did what I should’ve done from the beginning… just let the tiles move backwards and keep everything static with the player only moving up an down (as how I stated at the beginning of FlappyBirdgodot devlog 1 but didn’t actually follow).
Moved the set_process methodology to their own scripts, instead of handling everything in main.gd while also taking advantage of how signals work now. Instead of doing:

func _ready():
-    Event.game_pause.connect(_on_game_pause)
-
-func _on_game_pause(pause: bool):
-    set_process(pause)
-

Just connecting to set_process is enough:

func _ready():
-    Event.game_pause.connect(set_process)
-    # and when the signal doesn't send anything:
-    Event.game_start.connect(set_process.bind(true))
-    Event.game_over.connect(set_process.bind(false))
-

Improvements¶

Background parallax¶

First thing was to add a moving background functionality, by adding 2 of the same Sprite2D‘s one after another and everytime the first sprite moves out of the screen, position it right after the second sprite. Some sample code to accomplish this:

func _ready():
-   # Sprite2D and CompressedTexture2D nodes
-   background_orig.texture = background_texture
-   texture_size = background_orig.texture.get_size()
-
-   backgrounds.append(background_orig.duplicate())
-   backgrounds.append(background_orig.duplicate())
-   backgrounds[1].position = background_orig.position + Vector2(texture_size.x, 0.0)
-
-   add_child(backgrounds[0])
-   add_child(backgrounds[1])
-   background_orig.visible = false
-
-# ifirst (index first) it's a boolean value starting with false and
-#   its a hacky way of tracking the first sprites
-#   (the one closest to the left of the screen) in the array
-func _process(delta: float):
-    for background in backgrounds:
-        background.move_local_x(- SPEED * delta)
-
-    # moves the sprite that just exited the screen to the right of the upcoming sprite
-    if backgrounds[int(ifirst)].position.x <= - background_orig.position.x:
-        backgrounds[int(ifirst)].position.x = backgrounds[int(!ifirst)].position.x + texture_size.x
-        ifirst = !ifirst
-

Then I added background parallax by separating the background sprites in two: background and “foreground” (the buildings in the original sprites). And to move them separately just applied the same logic described above with 2 different speeds.

Sprite switcher¶

Also added a way to select between the bird sprites and the backgrounds, currently pretty primitive but functional. Accomplished this by holding textures in an exported array, then added a bit of logic to cycle between them (example for the background):

func _get_new_sprite_index(index: int) -> int:
-    return clampi(index, 0, background_textures.size() - 1)
-
-
-func _set_sprites_index(index: int) -> int:
-    var new_index: int = _get_new_sprite_index(index)
-    if new_index == itexture:
-        return new_index
-    for bg in backgrounds:
-        bg.texture = background_textures[new_index]
-    for fg in foregrounds:
-        fg.texture = foreground_textures[new_index]
-    itexture = new_index
-    return new_index
-

Then, in custom signals I just call _set_sprites_index with a texture_index +/- 1.

Save data¶

Moved from manual ConfigFile (which is an .ini file basically) to Resource which is easier to work with and faster to implement.

Accomplished by defining a new data_resource.gd:

class_name DataResource
-extends Resource
-
-@export var high_score: int
-@export var volume: float
-@export var mute: bool
-@export var bird: int
-@export var background: int
-
-func _init():
-    high_score = 0
-    volume = 0.5
-    mute = false
-    bird = 0
-    background = 0
-

Where the @exports are not needed unless you need to manage the .tres resource files for testing in-editor.

Then, the data.gd script needs to be changed accordingly, most notably:

The file extension is .tres instead of .cfg.
No need for “config sections”.
Saving changes to:

func save():
-    var err: int = ResourceSaver.save(_data, DATA_PATH)
-    if err != OK:
-        print("[ERROR] Couldn't save data.")
-

The loader gets simplified (mostly because the default values are set in the _init() function of the data_resource.gd) to:

func _load_data():
-    if ResourceLoader.exists(DATA_PATH):
-        _data = load(DATA_PATH)
-    else:
-        _data = DataResource.new()
-        save()
-

The attributes/config/saved data can be retrieved directly by the data_resource.gd variable name, for example: instead of _data.get_value(SCORE_SECTION, "high_score") it’s now simply _data.high_score. And similar for setting the values.

Compared to the 3.x version it is a lot more simple. Though I still have setters and getters for each attribute/config (I’ll se how to change this in the future).

Android¶

I did add android support but it’s been so long since I did it that I actually don’t remember (this entry has been sitting in a draft for months). In general I followed the official guide for Exporting for Android, setting up Android studio and remotely debugging with my personal phone; it does take a while to setup but after that it’s as simple as doing “one click deploys”.

Most notably, I had to enable touch screen support and make the buttons clickable either by an actual mouse click or touch input. Some of the Project Settings that I remember that needs changes are:

display/window/handheld/orientation set to Portrait.
input_devices/pointing/emulate_touch_from_mouse and input_devices/pointing/emulate_mouse_from_touch both set to on.

Misc¶

Found a bug on the ScoreDetector where it would collide with the Ceiling. While this is really not a problem outside of me doing tests I fixed it by applying the correct layer/mask.

- -

- - - - - Index - - - - - - - Previous - - -

- - -

By David Luévano

Created: Fri, Mar 01, 2024 @ 10:00 UTC

Modified: Fri, Mar 01, 2024 @ 10:11 UTC

Tags: -english, gamedev, gdscript, godot

- -

Creating my Go Godot Jam 3 entry using Godot 3.5 devlog 1

- -

The jam’s theme is Evolution and all the details are listed here. ~~This time I’m logging as I go, so there might be some changes to the script or scenes along the way.~~ I couldn’t actually do this, as I was running out of time. Note that I’m not going to go into much details, the obvious will be ommitted.

I wanted to do a Snake clone, and I’m using this jam as an excuse to do it and add something to it. The features include:

Snakes will pass their stats in some form to the next snakes.
Non-grid snake movement. I just hate the grid constraint, so I wanted to make it move in any direction.
Depending on the food you eat, you’ll gain new mutations/abilities ~~and the more you eat the more that mutation develops~~ didn’t have time to add this feature, sad.
Procedural map creation.

I created this game using Godot 3.5-rc3. You can find the source code in my GitHub here which at the time of writing this it doesn’t contain any exported files, for that you can go ahead and play it in your browser at itch.io, which you can find below:

<a href="https://lorentzeus.itch.io/snake-tronic">Snake-tronic by Lorentzeus</a>

- -

You can also find the jam entry here.

Similarly with the my FlappyBird clone, I plan to update this to a better state.

Table of contents¶

Table of contents
Initial setup
Assets
The snake
-
The food
Za warudo! (The world)
- Food placement
-
Stats clas and loading/saving data
- Stats class
- Load/save data
-
Scoring
Snake redesigned with the state machine pattern
Other minor stuff
Final notes

Initial setup¶

Again, similar to the FlappyBird clone I created, I’m using the directory structure I wrote about on Godot project structure with slight modifications to test things out. Also using similar Project settings as those from the FlappyBird clone like the pixel art texture imports, keybindings, layers, etc..

I’ve also setup GifMaker, with slight modifications as the AssetLib doesn’t install it correctly and contains unnecessry stuff: moved necessary files to the res://addons directory, deleted test scenes and files in general, and copied the license to the res://docs directory. Setting this up was a bit annoying because the tutorial it’s bad (with all due respect). I might do a separate entry just to explain how to set it up, because I couldn’t find it anywhere other than by inspecting some of the code/scenes. I ended up leaving this disabled in the game as it hit the performance by a lot, but it’s an option I’ll end up researching more.

This time I’m also going to be using an Event bus singleton (which I’m going to just call Event) as managing signals was pretty annoying on my last project; as well as a Global singleton for essential stuff so I don’t have to do as many cross references between nodes/scenes.

Assets¶

This time I’ll be creating my own assets in Aseprite, wont be that good, but enough to prototype and get things going.

Other than that I used few key sprites from vryell: Controller & Keyboard Icons and a font from datagoblin: Monogram.

The snake¶

This is the most challenging part in my opinion as making all the body parts follow the head in a user defined path it’s kinda hard. I tried with like 4-5 options and the one I’m detailing here is the only one that worked as I wanted for me. This time the directory structure I’m using is the following:

Basic movement¶

The most basic thing is to move the head, this is what we have control of. Create a scene called Head.tscn and setup the basic KinematicBody2D with it’s own Sprite and CollisionShape2D (I used a small circle for the tip of the head), and set the Collision Layer/Mask accordingly, for now just layer = bit 1. And all we need to do, is keep moving the snake forwards and be able to rotate left or right. Created a new script called head.gd attached to the root (KinematicBody2D) and added:

extends KinematicBody2D
-
-enum {
-    LEFT=-1,
-    RIGHT=1
-}
-
-var velocity: Vector2 = Vector2.ZERO
-var _direction: Vector2 = Vector2.UP
-
-
-func _physics_process(delta: float) -> void:
-    if Input.is_action_pressed("move_left"):
-        _rotate_to(LEFT)
-    if Input.is_action_pressed("move_right"):
-        _rotate_to(RIGHT)
-
-    velocity = _direction * Global.SNAKE_SPEED
-
-    velocity = move_and_slide(velocity)
-    _handle_time_elapsed(delta)
-
-
-func _rotate_to(direction: int) -> void:
-    rotate(deg2rad(direction * Global.SNAKE_ROT_SPEED * get_physics_process_delta_time()))
-    _direction = _direction.rotated(deg2rad(direction * Global.SNAKE_ROT_SPEED * get_physics_process_delta_time()))
-

After tunning all the necessary parameters you should get something like this:

Snake - Basic movement (left and right controls)

Setting up path following¶

To move other snake parts by following the snake head the only solution I found was to use the Path2D and PathFollow2D nodes. Path2D basically just handles the curve/path that PathFollow2D will use to move its child node; and I say “child node” in singular… as PathFollow2D can only handle one damn child, all the other ones will have weird transformations and/or rotations. So, the next thing to do is to setup a way to compute (and draw so we can validate) the snake’s path/curve.

Added the signal snake_path_new_point(coordinates) to the Event singleton and then add the following to head.gd:

var _time_elapsed: float = 0.0
-
-# using a timer is not recommended for < 0.01
-func _handle_time_elapsed(delta: float) -> void:
-    if _time_elapsed >= Global.SNAKE_POSITION_UPDATE_INTERVAL:
-        Event.emit_signal("snake_path_new_point", global_position)
-        _time_elapsed = 0.0
-    _time_elapsed += delta
-

This will be pinging the current snake head position every 0.01 seconds (defined in Global). Now create a new scene called Snake.tscn which will contain a Node2D, a Path2D and an instance of Head as its childs. Create a new script called snake.gd attached to the root (Node2D) with the following content:

class_name Snake
-extends Node2D
-
-onready var path: Path2D = $Path
-
-func _ready():
-    Event.connect("snake_path_new_point", self, "_on_Head_snake_path_new_point")
-
-
-func _draw() -> void:
-    if path.curve.get_baked_points().size() >= 2:
-        draw_polyline(path.curve.get_baked_points(), Color.aquamarine, 1, true)
-
-
-func _on_Head_snake_path_new_point(coordinates: Vector2) -> void:
-    path.curve.add_point(coordinates)
-    # update call is to draw curve as there are new points to the path's curve
-    update()
-

With this, we’re now populating the Path2D curve points with the position of the snake head. You should be able to see it because of the _draw call. If you run it you should see something like this:

Define body parts for the snake¶

At this point the only thing to do is to add the corresponding next body parts and tail of the snake. To do so, we need a PathFollow2D to use the live-generating Path2D, the only caveat is that we need one of these per body part/tail (this took me hours to figure out, thanks documentation).

Create a new scene called Body.tscn with a PathFollow2D as its root and an Area2D as its child, then just add the necessary Sprite and CollisionShap2D for the Area2D, I’m using layer = bit 2 for its collision. Create a new script called generic_segment.gd with the following code:

extends PathFollow2D
-
-export(String, "body", "tail") var TYPE: String = "body"
-
-
-func _physics_process(delta: float) -> void:
-    offset += Global.SNAKE_SPEED * delta
-

And this can be attached to the Body‘s root node (PathFollow2D), no extra setup needed. Repeat the same steps for creating the Tail.tscn scene and when attaching the generic_segment.gd script just configure the Type parameter to tail in the GUI (by selecting the node with the script attached and editing in the Inspector).

Adding body parts¶

Now it’s just a matter of handling when to add new body parts in the snake.gd script. For now I’ve only setup for adding body parts to fulfill the initial length of the snake (this doesn’t include the head or tail). The extra code needed is the following:

export(PackedScene) var BODY_SEGMENT_NP: PackedScene
-export(PackedScene) var TAIL_SEGMENT_NP: PackedScene
-
-var current_body_segments: int = 0
-var max_body_segments: int = 1
-
-
-func _add_initial_segment(type: PackedScene) -> void:
-    if path.curve.get_baked_length() >= (current_body_segments + 1.0) * Global.SNAKE_SEGMENT_SIZE:
-        var _temp_body_segment: PathFollow2D = type.instance()
-        path.add_child(_temp_body_segment)
-        current_body_segments += 1
-
-
-func _on_Head_snake_path_new_point(coordinates: Vector2) -> void:
-    path.curve.add_point(coordinates)
-    # update call is to draw curve as there are new points to the path's curve
-    update()
-
-    # add the following lines
-    if current_body_segments < max_body_segments:
-        _add_initial_segment(BODY_SEGMENT_NP)
-    elif current_body_segments == max_body_segments:
-        _add_initial_segment(TAIL_SEGMENT_NP)
-

Select the Snake node and add the Body and Tail scene to the parameters, respectively. Then when running you should see something like this:

Snake - Basic movement with all body parts

Now, we need to handle adding body parts after the snake is complete and already moved for a bit, this will require a queue so we can add part by part in the case that we eat multiple pieces of food in a short period of time. For this we need to add some signals: snake_adding_new_segment(type), snake_added_new_segment(type), snake_added_initial_segments and use them when makes sense. Now we need to add the following:

var body_segment_stack: Array
-var tail_segment: PathFollow2D
-# didn't konw how to name this, basically holds the current path lenght
-#   whenever the add body segment, and we use this stack to add body parts
-var body_segment_queue: Array
-

As well as updating _add_initial_segment with the following so it adds the new segment on the specific variable:

if _temp_body_segment.TYPE == "body":
-    body_segment_stack.append(_temp_body_segment)
-else:
-    tail_segment = _temp_body_segment
-

Now that it’s just a matter of creating the segment queue whenever a new segment is needed, as well as adding each segment in a loop whenever we have items in the queue and it’s a good distance to place the segment on. These two things can be achieved with the following code:

# this will be called in _physics_process
-func _add_new_segment() -> void:
-    var _path_length_threshold: float = body_segment_queue[0] + Global.SNAKE_SEGMENT_SIZE
-    if path.curve.get_baked_length() >= _path_length_threshold:
-        var _removed_from_queue: float = body_segment_queue.pop_front()
-        var _temp_body_segment: PathFollow2D = BODY_SEGMENT_NP.instance()
-        var _new_body_offset: float = body_segment_stack.back().offset - Global.SNAKE_SEGMENT_SIZE
-
-        _temp_body_segment.offset = _new_body_offset
-        body_segment_stack.append(_temp_body_segment)
-        path.add_child(_temp_body_segment)
-        tail_segment.offset = body_segment_stack.back().offset - Global.SNAKE_SEGMENT_SIZE
-
-        current_body_segments += 1
-
-
-func _add_segment_to_queue() -> void:
-    # need to have the queues in a fixed separation, else if the eating functionality
-    #   gets spammed, all next bodyparts will be spawned almost at the same spot
-    if body_segment_queue.size() == 0:
-        body_segment_queue.append(path.curve.get_baked_length())
-    else:
-        body_segment_queue.append(body_segment_queue.back() + Global.SNAKE_SEGMENT_SIZE)
-

With everything implemented and connected accordingly then we can add segments on demand (for testing I’m adding with a key press), it should look like this:

Snake - Basic movement with dynamic addition of new segments

For now, this should be enough, I’ll add more stuff as needed as I go. Last thing is that after finished testing that the movement felt ok, I just added a way to stop the snake whenever it collides with itself by using the following code (and the signal snake_segment_body_entered(body)) in a main.gd script that is the entry point for the game:

func _snake_disabled(on_off: bool) -> void:
-    _snake.propagate_call("set_process", [on_off])
-    _snake.propagate_call("set_process_internal", [on_off])
-    _snake.propagate_call("set_physics_process", [on_off])
-    _snake.propagate_call("set_physics_process_internal", [on_off])
-    _snake.propagate_call("set_process_input", [on_off])
-

Which will stop the snake node and all children.

Fix on body segments following head¶

After a while of testing and developing, I noticed that sometimes the head “detaches” from the body when a lot of rotations happen (moving the snake left or right), because of how imprecise the Curve2D is. To do this I just send a signal (snake_rotated) whenever the snake rotates and make a small correction (in generic_segment.gd):

func _on_snake_rotated() -> void:
-    offset -= 0.75 * Global.SNAKE_SPEED * pow(get_physics_process_delta_time(), 2)
-

This is completely random, I tweaked it manually after a lot of iterations.

The food¶

For now I just decided to setup a simple system to see everything works fine. The idea is to make some kind of generic food node/scene and a “food manager” to spawn them, for now in totally random locations. For this I added the following signals: food_placing_new_food(type), food_placed_new_food(type) and food_eaten(type).

First thing is creating the Food.tscn which is just an Area2D with its necessary children with an attached script called food.gd. The script is really simple:

class_name Food # needed to access Type enum outside of the script, this registers this script as a node
-extends Area2D
-
-enum Type {
-    APPLE
-}
-
-var _type_texture: Dictionary = {
-    Type.APPLE: preload("res://entities/food/sprites/apple.png")
-}
-
-export(Type) var TYPE
-onready var _sprite: Sprite = $Sprite
-
-
-func _ready():
-    connect("body_entered", self, "_on_body_entered")
-    _sprite.texture = _type_texture[TYPE]
-
-
-func _on_body_entered(body: Node) -> void:
-    Event.emit_signal("food_eaten", TYPE)
-    queue_free()
-

Then this food_eaten signal is received in snake.gd to add a new segment to the queue.

Finally, for the food manager I just created a FoodManager.tscn with a Node2D with an attached script called food_manager.gd. To get a random position:

func _get_random_pos() -> Vector2:
-    var screen_size: Vector2 = get_viewport().get_visible_rect().size
-    var temp_x: float = randf() * screen_size.x - screen_size.x / 2.0
-    var temp_y: float = randf() * screen_size.y - screen_size.y / 2.0
-
-    return Vector2(temp_x, temp_y)
-

Which gets the job done, but later I’ll have to add a way to check that the position is valid. And to actually place the food:

func _place_new_food() -> void:
-    var food: Area2D = FOOD.instance()
-    var position: Vector2 = _get_random_pos()
-    food.global_position = position
-    add_child(food)
-

And this is used in _process to place new food whenever needed. For now I added a condition to add food until 10 pieces are in place, and keep adding whenever the food is is lower than 10. After setting everything up, this is the result:

Za warudo! (The world)¶

It just happend that I saw a video to create random maps by using a method called random walks, this video was made by NAD LABS: Nuclear Throne Like Map Generation In Godot. It’s a pretty simple but powerful script, he provided the source code from which I based my random walker, just tweaked a few things and added others. Some of the maps than can be generated with this method (already aded some random sprites):

It started with just black and white tiles, but I ended up adding some sprites as it was really harsh to the eyes. My implementation is basically the same as NAD LABS‘ with few changes, most importantly: I separated the generation in 2 diferent tilemaps (floor and wall) to have better control as well as wrapped everything in a single scene with a “main” script with the following important functions:

func get_valid_map_coords() -> Array:
-    var safe_area: Array = walker_head.get_cells_around()
-    var cells_used: Array = ground_tilemap.get_used_cells()
-    for location in safe_area:
-        cells_used.erase(location)
-    return cells_used
-
-
-func get_centered_world_position(location: Vector2) -> Vector2:
-    return ground_tilemap.map_to_world(location) + Vector2.ONE * Global.TILE_SIZE / 2.0
-

Where get_cells_around is just a function that gets the safe cells around the origin. And this get_valid_map_coords just returns used cells minus the safe cells, to place food. get_centered_world_position is so we can center the food in the tiles.

Some signals I used for the world gen: world_gen_walker_started(id), world_gen_walker_finished(id), world_gen_walker_died(id) and world_gen_spawn_walker_unit(location).

Food placement¶

The last food algorithm doesn’t check anything related to the world, and thus the food could spawn in the walls and outside the map.

First thing is I generalized the food into a single script and added basic food and special food which inherit from base food. The most important stuff for the base food is to be able to set all necessary properties at first:

func update_texture() -> void:
-    _sprite.texture = texture[properties["type"]]
-
-
-func set_properties(pos: Vector2, loc: Vector2, special: bool, type: int, points: int=1, special_points: int=1, ttl: float = -1.0) -> void:
-    properties["global_position"] = pos
-    global_position = pos
-    properties["location"] = loc
-    properties["special"] = special
-    properties["type"] = type
-
-    properties["points"] = points
-    properties["special_points"] = special_points
-    properties["ttl"] = ttl
-    if properties["ttl"] != -1.0:
-        timer.wait_time = properties["ttl"]
-        timer.start()
-

Where the update_texture needs to be a separate function, because we need to create the food first, set properties, add as a child and then update the sprite; we also need to keep track of the global position, location (in tilemap coordinates) and identifiers for the type of food.

Then basic/special food just extend base food, define a Type enum and preloads the necessary textures, for example:

enum Type {
-    APPLE,
-    BANANA,
-    RAT
-}
-
-
-func _ready():
-    texture[Type.APPLE] = preload("res://entities/food/sprites/apple.png")
-    texture[Type.BANANA] = preload("res://entities/food/sprites/banana.png")
-    texture[Type.RAT] = preload("res://entities/food/sprites/rat.png")
-

Now, some of the most important change to food_manager.gd is to get an actual random valid position:

func _get_random_pos() -> Array:
-    var found_valid_loc: bool = false
-    var index: int
-    var location: Vector2
-
-    while not found_valid_loc:
-        index = randi() % possible_food_locations.size()
-        location = possible_food_locations[index]
-        if current_basic_food.find(location) == -1 and current_special_food.find(location) == -1:
-            found_valid_loc = true
-
-    return [world_generator.get_centered_world_position(location), location]
-

Other than that, there are some differences between placing normal and special food (specially the signal they send, and if an extra “special points” property is set). Some of the signals that I used that might be important: food_placing_new_food(type), food_placed_new_food(type, location) and food_eaten(type, location).

Stats clas and loading/saving data¶

I got the idea of saving the current stats (points, max body segments, etc.) in a separate Stats class for easier load/save data. This option I went with didn’t work as I would liked it to work, as it was a pain in the ass to setup and each time a new property is added you have to manually setup the load/save helper functions… so not the best option. This option I used was json but saving a Node directly could work better or using resources (saving tres files).

Stats class¶

The Stats “class” is just a script that extends from Node called stats.gd. It needs to define the class_name as Stats. The main content:

# main
-var points: int = 0
-var segments: int = 0
-
-# track of trait points
-var dash_points: int = 0
-var slow_points: int = 0
-var jump_points: int = 0
-
-# times trait achieved
-var dash_segments: int = 0
-var slow_segments: int = 0
-var jump_segments: int = 0
-
-# trait properties
-var dash_percentage: float = 0.0
-var slow_percentage: float = 0.0
-var jump_lenght: float = 0.0
-
-# trait active
-var trait_dash: bool = false
-var trait_slow: bool = false
-var trait_jump: bool = false
-

And with the ugliest functions:

func get_stats() -> Dictionary:
-    return {
-        "points": points,
-        "segments": segments,
-        "dash_points": dash_points,
-        "dash_segments": dash_segments,
-        "dash_percentage": dash_percentage,
-        "slow_points": slow_points,
-        "slow_segments": slow_segments,
-        "slow_percentage": slow_percentage,
-        "jump_points": jump_points,
-        "jump_segments": jump_segments,
-        "jump_lenght": jump_lenght,
-        "trait_dash": trait_dash,
-        "trait_slow": trait_slow,
-        "trait_jump": trait_jump
-    }
-
-
-func set_stats(stats: Dictionary) -> void:
-        points = stats["points"]
-        segments = stats["segments"]
-        dash_points = stats["dash_points"]
-        slow_points = stats["slow_points"]
-        jump_points = stats["jump_points"]
-        dash_segments = stats["dash_segments"]
-        slow_segments = stats["slow_segments"]
-        jump_segments = stats["jump_segments"]
-        dash_percentage = stats["dash_percentage"]
-        slow_percentage = stats["slow_percentage"]
-        jump_lenght = stats["jump_lenght"]
-        trait_dash = stats["trait_dash"]
-        trait_slow = stats["trait_slow"]
-        trait_jump = stats["trait_jump"]
-

And this is not scalable at all, but I had to do this at the end of the jam so no way of optimizing and/or doing it correctly, sadly.

Load/save data¶

The load/save function is pretty standard. It’s a singleton/autoload called SavedData with a script that extends from Node called save_data.gd:

const DATA_PATH: String = "user://data.save"
-
-var _stats: Stats
-
-
-func _ready() -> void:
-    _load_data()
-
-
-# called when setting "stats" and thus saving
-func save_data(stats: Stats) -> void:
-    _stats = stats
-    var file: File = File.new()
-    file.open(DATA_PATH, File.WRITE)
-    file.store_line(to_json(_stats.get_stats()))
-    file.close()
-
-
-func get_stats() -> Stats:
-    return _stats
-
-
-func _load_data() -> void:
-    # create an empty file if not present to avoid error while loading settings
-    _handle_new_file()
-
-    var file = File.new()
-    file.open(DATA_PATH, File.READ)
-    _stats = Stats.new()
-    _stats.set_stats(parse_json(file.get_line()))
-    file.close()
-
-
-func _handle_new_file() -> void:
-    var file: File = File.new()
-    if not file.file_exists(DATA_PATH):
-        file.open(DATA_PATH, File.WRITE)
-        _stats = Stats.new()
-        file.store_line(to_json(_stats.get_stats()))
-        file.close()
-

It uses json as the file format, but I might end up changing this in the future to something else more reliable and easier to use (Stats class related issues).

Scoring¶

For this I created a scoring mechanisms and just called it ScoreManager (score_manager.gd) which just basically listens to food_eaten signal and adds points accordingly to the current Stats object loaded. The main function is:

func _on_food_eaten(properties: Dictionary) -> void:
-    var is_special: bool = properties["special"]
-    var type: int = properties["type"]
-    var points: int = properties["points"]
-    var special_points: int = properties["special_points"]
-    var location: Vector2 = properties["global_position"]
-    var amount_to_grow: int
-    var special_amount_to_grow: int
-
-    amount_to_grow = _process_points(points)
-    _spawn_added_score_text(points, location)
-    _spawn_added_segment_text(amount_to_grow)
-
-    if is_special:
-        special_amount_to_grow = _process_special_points(special_points, type)
-        # _spawn_added_score_text(points, location)
-        _spawn_added_special_segment_text(special_amount_to_grow, type)
-        _check_if_unlocked(type)
-

Where the most important function is:

func _process_points(points: int) -> int:
-    var score_to_grow: int = (stats.segments + 1) * Global.POINTS_TO_GROW - stats.points
-    var amount_to_grow: int = 0
-    var growth_progress: int
-    stats.points += points
-    if points >= score_to_grow:
-        amount_to_grow += 1
-        points -= score_to_grow
-        # maybe be careful with this
-        amount_to_grow += points / Global.POINTS_TO_GROW
-        stats.segments += amount_to_grow
-        Event.emit_signal("snake_add_new_segment", amount_to_grow)
-
-    growth_progress = Global.POINTS_TO_GROW - ((stats.segments + 1) * Global.POINTS_TO_GROW - stats.points)
-    Event.emit_signal("snake_growth_progress", growth_progress)
-    return amount_to_grow
-

Which will add the necessary points to Stats.points and return the amount of new snake segments to grow. After this _spawn_added_score_segment and _spawn_added_segment_text just spawn a Label with the info on the points/segments gained; this is custom UI I created, nothing fancy.

Last thing is taht in _process_points there is a check at the end, where if the food eaten is “special” then a custom variation of the last 3 functions are executed. These are really similar, just specific to each kind of food.

This ScoreManager also handles the calculation for the game_over signal, to calculte progress, set necessary Stats values and save the data:

func _on_game_over() -> void:
-    var max_stats: Stats = _get_max_stats()
-    SaveData.save_data(max_stats)
-    Event.emit_signal("display_stats", initial_stats, stats, mutation_stats)
-
-
-func _get_max_stats() -> Stats:
-    var old_stats_dict: Dictionary = initial_stats.get_stats()
-    var new_stats_dict: Dictionary = stats.get_stats()
-    var max_stats: Stats = Stats.new()
-    var max_stats_dict: Dictionary = max_stats.get_stats()
-    var bool_stats: Array = [
-        "trait_dash",
-        "trait_slow",
-        "trait_jump"
-    ]
-
-    for i in old_stats_dict:
-        if bool_stats.has(i):
-            max_stats_dict[i] = old_stats_dict[i] or new_stats_dict[i]
-        else:
-            max_stats_dict[i] = max(old_stats_dict[i], new_stats_dict[i])
-    max_stats.set_stats(max_stats_dict)
-    return max_stats
-

Then this sends a signal display_stats to activate UI elements that shows the progression.

Naturally, the saved Stats are loaded whenever needed. For example, for the Snake, we load the stats and setup any value needed from there (like a flag to know if any ability is enabled), and since we’re saving the new Stats at the end, then on restart we load the updated one.

Snake redesigned with the state machine pattern¶

I redesigned the snake code (the head, actually) to use the state machine pattern by following this guide which is definitely a great guide, straight to the point and easy to implement.

Other than what is shown in the guide, I implemented some important functions in the state_machine.gd script itself, to be used by each of the states as needed:

func rotate_on_input() -> void:
-    if Input.is_action_pressed("move_left"):
-        player.rotate_to(player.LEFT)
-    if Input.is_action_pressed("move_right"):
-        player.rotate_to(player.RIGHT)
-
-
-func slow_down_on_collisions(speed_backup: float):
-    if player.get_last_slide_collision():
-        Global.SNAKE_SPEED = player.velocity.length()
-    else:
-        Global.SNAKE_SPEED = speed_backup
-
-
-func handle_slow_speeds() -> void:
-    if Global.SNAKE_SPEED <= Global.SNAKE_SPEED_BACKUP / 4.0:
-        Global.SNAKE_SPEED = Global.SNAKE_SPEED_BACKUP
-        Event.emit_signal("game_over")
-

And then in the StateMachine‘s _process:

func _physics_process(delta: float) -> void:
-    # state specific code, move_and_slide is called here
-    if state.has_method("physics_process"):
-        state.physics_process(delta)
-
-    handle_slow_speeds()
-    player.handle_time_elapsed(delta)
-

And now it’s just a matter of implementing the necessary states. I used 4: normal_stage.gd, slow_state.gd, dash_state.gd and jump_state.gd.

The normal_state.gd contains what the original head.gd code contained:

func physics_process(delta: float) -> void:
-    fsm.rotate_on_input()
-    fsm.player.velocity = fsm.player.direction * Global.SNAKE_SPEED
-    fsm.player.velocity = fsm.player.move_and_slide(fsm.player.velocity)
-
-    fsm.slow_down_on_collisions(Global.SNAKE_SPEED_BACKUP)
-
-
-func input(event: InputEvent) -> void:
-    if fsm.player.can_dash and event.is_action_pressed("dash"):
-        exit("DashState")
-    if fsm.player.can_slow and event.is_action_pressed("slow"):
-        exit("SlowState")
-    if fsm.player.can_jump and event.is_action_pressed("jump"):
-        exit("JumpState")
-

Here, the exit method is basically to change to the next state. And lastly, I’m only gonna show the dash_state.gd as the other ones are pretty similar:

func enter():
-    if fsm.DEBUG:
-        print("Got inside %s." % name)
-    Event.emit_signal("snake_started_dash")
-    Global.SNAKE_SPEED = Global.SNAKE_DASH_SPEED
-    yield(get_tree().create_timer(Global.SNAKE_DASH_TIME), "timeout")
-    exit()
-
-
-func exit():
-    Event.emit_signal("snake_finished_dash")
-    Global.SNAKE_SPEED = Global.SNAKE_SPEED_BACKUP
-    fsm.back()
-
-
-func physics_process(delta: float) -> void:
-    fsm.rotate_on_input()
-    fsm.player.velocity = fsm.player.direction * Global.SNAKE_SPEED
-    fsm.player.velocity = fsm.player.move_and_slide(fsm.player.velocity)
-
-    fsm.slow_down_on_collisions(Global.SNAKE_DASH_SPEED)
-

Where the important parts happen in the enter and exit functions. We need to change the Global.SNAKE_SPEED with the Global.SNAKE_DASH_SPEED on startand start the timer for how long should the dash last. And on the exit we reset the Global.SNAKE_SPEED back to normal. There is probably a better way of updating the Global.SNAKE_SPEED but this works just fine.

For the other ones is the same. Only difference with the jump_state.gd is that the collision from head to body is disabled, and no rotation is allowed (by not calling the rotate_on_input function).

Other minor stuff¶

Not as important but worth mentioning:

Added restartability function.
Added signals for game control: game_over and game_start, but ended not using them.
Fixed issue where the Curve2D stayed the same even when restarting by just setting an empty curve on starting the node.
Added a debug mode for drawing of the Curve2D instead of always drawing.
Tweaked the tracking of the snake size.
Tweaked the food system to contain more attributes and use a base food node.
Added a HUD with mini snake sprites.
Added a HUD for growth progress on snake body segments and abilities.
Refactored the nodes to make it work with change_scene_to, and added a main menu.
Added GUI for dead screen, showing the progress.

Final notes¶

I actually didn’t finish this game (as how I visualized it), but I got it in a semi-playable state which is good. My big learning during this jam is the time management that it requires to plan and design a game. I lost a lot of time trying to implement some mechanics because I was facing many issues, because of my lack of practice (which was expected) as well as trying to blog and create the necessary sprites myself. Next time I should just get an asset pack and do something with it, as well as keeping the scope of my game shorter.

For exporting and everything else, I went with what I did for my FlappyBird Godot clone: final notes and exporting

- -

- - - - Next - - - - - - - Index - - - - - - - Previous - - -

- - -

By David Luévano

Created: Fri, Jun 10, 2022 @ 09:17 UTC

Modified: Thu, May 04, 2023 @ 17:05 UTC

Tags: -english, gamedev, gamejam, gdscript, godot

- -

Creating a FlappyBird clone in Godot 3.5 devlog 1

Table of contents¶

Initial setup¶

Directory structure¶

Config¶

Default import settings¶

General settings¶

Keybindings¶

Layers¶

Assets¶

Importing¶

Scenes¶

TileMaps¶

Default ground tiles¶

Player¶

Other¶

Game¶

UI¶

Fonts¶

Scene setup¶

Main¶

Scripting¶

Player¶

WorldDetector¶

WorldTiles¶

GroundTileMap¶

PipeTileMap¶

Saved data¶

Game¶

UI¶

Main¶

Final notes and exporting¶

Preparing the files¶

Exporting¶

Porting the FlappyBird clone to Godot 4.1 devlog 2

Table of contents¶

Porting to Godot 4¶

General changes¶

Player¶

World¶

Scene¶

Script¶

Changes and improvements¶

Audio¶

Event bus¶

UI¶

Misc¶

Final improvements to the FlappyBird clone and Android support devlog 3

Table of contents¶

Refactoring¶

Improvements¶

Background parallax¶

Sprite switcher¶

Save data¶

Android¶

Misc¶

Godot layers and masks notes

General Godot project structure

Creating my Go Godot Jam 3 entry using Godot 3.5 devlog 1

Table of contents¶

Initial setup¶

Assets¶

The snake¶

Basic movement¶

Setting up path following¶

Define body parts for the snake¶

Adding body parts¶

Fix on body segments following head¶

The food¶

Za warudo! (The world)¶

Food placement¶

Stats clas and loading/saving data¶

Stats class¶

Load/save data¶

Scoring¶

Snake redesigned with the state machine pattern¶

Other minor stuff¶

Final notes¶

Will start blogging about gamedev